@echo off
title ONE-FIX Agent Uninstall
rem ============================================================
rem  ONE-FIX agent uninstall launcher (seolren.com)
rem  Removes agent completely: service, tray task, files, ARP.
rem  Keeps RustDesk and scan account/folder.
rem  Uses local uninstall-agent.ps1 if next to this bat,
rem  otherwise downloads from seolren.com.
rem  Served at: https://seolren.com/downloads/onefix-agent-uninstall.bat
rem ============================================================

net session >nul 2>&1
if %errorlevel% == 0 goto :run

echo.
echo  Requesting administrator rights (UAC)...
powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
exit /b

:run
set "PSFILE=%ProgramData%\onefix-uninstall-agent.ps1"
if exist "%~dp0uninstall-agent.ps1" (
    copy /y "%~dp0uninstall-agent.ps1" "%PSFILE%" >nul
    goto :exec
)
echo.
echo  Downloading uninstall script...
powershell -NoProfile -ExecutionPolicy Bypass -Command "[Net.ServicePointManager]::SecurityProtocol='Tls12'; iwr 'https://seolren.com/downloads/uninstall-agent.ps1' -UseBasicParsing -OutFile '%PSFILE%'"
if not exist "%PSFILE%" (
    echo  [X] Download failed - check internet connection.
    pause
    exit /b 1
)

:exec
powershell -NoProfile -ExecutionPolicy Bypass -File "%PSFILE%"
del "%PSFILE%" >nul 2>&1
echo.
pause